cy/nixos-config
cy/nixos-config
1
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity

chezmoi init

Browse source
This commit is contained in:
Cy Pokhrel 2024-10-22 11:11:45 -04:00
commit 530d6d7195
No known key found for this signature in database
GPG key ID: 1200FBE36C2ADE2E
1176 changed files with 111325 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

14
dot_oh-my-zsh/plugins/sdk/README.md Normal file
View file

@ -0,0 +1,14 @@
# sdk
Plugin for SDKMAN, a tool for managing parallel versions of multiple Software Development Kits on most Unix based systems.
Provides autocompletion for all known commands.
To use it, add `sdk` to your plugins array in your zshrc file:
```zsh
plugins=(... sdk)
```
## Requirements
* [SDKMAN](http://sdkman.io/)

58
dot_oh-my-zsh/plugins/sdk/sdk.plugin.zsh Normal file
View file

@ -0,0 +1,58 @@
#!/usr/bin/env zsh
### SDKMAN Autocomplete for Oh My Zsh
_sdk() {
case "${CURRENT}" in
2)
compadd -X $'Commands:\n' -- "${${(Mk)functions[@]:#__sdk_*}[@]#__sdk_}"
compadd -n rm
;;
3)
case "${words[2]}" in
l|ls|list|i|install)
compadd -X $'Candidates:\n' -- "${SDKMAN_CANDIDATES[@]}"
;;
ug|upgrade|h|home|c|current|u|use|d|default|rm|uninstall)
compadd -X $'Installed Candidates:\n' -- "${${(u)${(f)$(find -L -- "${SDKMAN_CANDIDATES_DIR}" -mindepth 2 -maxdepth 2 -type d)}[@]:h}[@]:t}"
;;
e|env)
compadd init
;;
offline)
compadd enable disable
;;
selfupdate)
compadd force
;;
flush)
compadd archives broadcast temp version
;;
esac
;;
4)
case "${words[2]}" in
i|install)
setopt localoptions kshglob
if [[ "${words[3]}" == 'java' ]]; then
compadd -X $'Installable Versions of java:\n' -- "${${${${${(f)$(__sdkman_list_versions "${words[3]}")}[@]:5:-4}[@]:#* | (local only|installed ) | *}[@]##* | | }[@]%%+( )}"
else
compadd -X "Installable Versions of ${words[3]}:"$'\n' -- "${${(z)${(M)${(f)${$(__sdkman_list_versions "${words[3]}")//[*+>]+( )/-}}[@]:# *}[@]}[@]:#-*}"
fi
;;
h|home|u|use|d|default|rm|uninstall)
compadd -X "Installed Versions of ${words[3]}:"$'\n' -- "${${(f)$(find -L -- "${SDKMAN_CANDIDATES_DIR}/${words[3]}" -mindepth 1 -maxdepth 1 -type d -not -name 'current')}[@]:t}"
;;
esac
;;
5)
case "${words[2]}" in
i|install)
_files -X "Path to Local Installation of ${words[3]} ${words[4]}:"$'\n' -/
;;
esac
;;
esac
}
compdef _sdk sdk